[dugongs0]     Dugongs: nonlinear growth curve

Carlin and Gelfand (1991) present a nonconjugate Bayesian analysis of the following data set from Ratkowsky (1983):
[dugongs1]
The data are length and age measurements for 27 captured dugongs (sea cows). Carlin and Gelfand (1991) model this data using a nonlinear growth curve with no inflection point and an asymptote as X i tends to infinity:

   Y i ~ Normal( m i , t ),   i = 1,...,27
   
    m i = a - bg Xi     a , b > 0; 0 < g < 1

Standard noninformative priors are adopted for a , b and t , and a uniform prior on (0,1) is assumed for g . However, this specification leads to a non conjugate full conditional distribution for g which is also non log-concave. The graph and corresponding BUGS code is given below


[dugongs2]


   model
   {
      for( i in 1 : N ) {
         Y[i] ~ dnorm(mu[i], tau)
         mu[i] <- alpha - beta * pow(gamma,x[i])   
      }
      alpha ~ dnorm(0.0, 1.0E-6)I(0,)
      beta ~ dnorm(0.0, 1.0E-6)I(0,)
      gamma ~ dunif(0.5, 1.0)
      tau ~ dgamma(0.001, 0.001)
      sigma <- 1 / sqrt(tau)
      U3 <- logit(gamma)   
   }

 Data ( click to open )


Inits ( click to open )

Results

A 1000 update burn in followed by a further 10000 updates gave the parameter estimates

[dugongs3]


model
   {
      for( i in 1 : N ) {
         Y[i] ~ dnorm(mu[i], tau)
         mu[i] <- alpha - beta * pow(gamma,x[i])         
      }
      alpha ~ dnorm(0.0, 1.0E-6)
      beta ~ dnorm(0.0, 1.0E-6)
      logit(gamma) <- U3
      tau ~ dgamma(0.001, 0.001)
      sigma <- 1 / sqrt(tau)
      U3 ~ dnorm(0, 1.0E-4)
   }
   
list (alpha = 1, beta = 1, tau = 1, U3 = 0)

       mean   sd   MC_error   val2.5pc   median   val97.5pc   start   sample
   U3   1.912   0.2609   0.01072   1.415   1.904   2.459   2001   9000
   alpha   2.665   0.07564   0.002835   2.544   2.655   2.848   2001   9000
   beta   0.9753   0.07757   0.00325   0.8274   0.9752   1.132   2001   9000
   gamma   0.8684   0.02941   0.00123   0.8046   0.8704   0.9212   2001   9000
   sigma   0.09871   0.01474   2.373E-4   0.07482   0.09716   0.1321   2001   9000